Compositional research on dissonance curves

Talk presented at the SuperCollider Symposium 07

Juan S. Lach Lau


Roughness:


Sensations of 'beating' and 'roughness' are fluctuations of amplitude that occur due to constructive and destructive interference of sound waves. 


The term 'roughness' is analogous to a tactile sensation in the sense of small irregularities in the perception of sound. 


The rate of amplitude fluctuation formed by two overlapping sound waves is equal to their difference in Hz. Sound waves with a difference lower than 20Hz produce slow fluctuations perceived as tremolo or 'beating'. Faster fluctuations are responsible for sensations of roughness at differences of frequencies (or musical intervals) that depend on the register of hearing. 


This variation is a function of cochlear physiology: the critical bandwidth. 


f = [37,52,74,105,149,210,297,420,595,841,1189,1682,2378,3364,4757,6727,9514,13454]; // Hz

a = f.asBark.criticalBW;

// x = log frequency, y = size of critical bandwidth:

f.collect{|x,i| x + a[i]}.plot; // in hertz

f.collect{|x,i| x.cents(x+a[i]).abs}.plot; // in cents


b = Array.series(60, 0, 0.2).barkToHz; // a scale made of 0.2 bark steps

Pbind(\freq, Pseq(b,1), \dur, 0.25).play;


There has been strong musicological debate over concepts of consonance and dissonance and how these phenomena occur. Perception of dissonance is held as influenced by cultural and sensory factors. Acquired factors are many and dependent on the tradition and practice of different musics. Innate factors (physiological mechanisms) have been the focus of psychoacoustic dissonance, leading to a concept of dissonance based on sensorial aspects of sound, also know as sensory dissonance, a term coined by Helmholtz (1877) who first researched on the principles behind dissonance perception as amplitude fluctuations generated by spectral components of sound. It depends on alignments of partials as well as the interval between them and their register. 


Vassilakis (2001 [1]), writes: “Sound variations involving this sensation are found in most musical traditions. In the Western musical tradition, the sensation of roughness has often been linked to the concepts of consonance and dissonance, whether those have been understood as aesthetically loaded [...] or [...] not. Studies addressing this sensation have occasionally been too keen to find a definite and universally acceptable justification to the 'natural inevitability' and 'aesthetic superiority' of Western music theory. This has prevented them from seriously examining the physical and physiological correlates of the roughness sensation. On the contrary, Helmholtz, the first researcher to examine roughness theoretically and experimentally as an important attribute of auditory sensation, concluded: 


Whether one combination [of tones] is rougher or smoother than another 

depends solely on the anatomical structure of the ear, and has nothing to do 

with psychological motives. But what degree of roughness a hearer is inclined

to ... as a means of musical expression depends on taste and habit; hence the 

boundary between consonances and dissonances has frequently changed ... 

and will still further change...”


In summary, after Helmholtz we have: 


von Békésy (1930's): basilar membrane and cochlear physiology 

Fletcher-Mundson(1930's): equal loudness contours

Zwicker (1957): critical bandwidth measurements

Plomp-Levelt (1965): relating & measuring CB with tonal consonance

Terhardt, Parncutt, etc.: virtual-pitch, pitch salience, etc.


// a dissonance curve for 1 partial gives the Plomp & Levelt curve 

// (roughness as a function of frequency) 

Dissonance.make([100],[1],1.0, 2.5).plot;


// Roughness of sine waves in barks:

//execute first, then define one of the arrays that follow and then execute last line:

(

SynthDef(\sine, {|freq = 440, amp = 0.005, pan = 0|

var env = EnvGen.kr(Env.asr(0.1, amp, 0.2), doneAction:2);

Out.ar(0, Pan2.ar(SinOsc.ar(freq), pan, env))

}).memStore;

z = ();

z.win = SCWindow("rough", Rect(65, 90, 150,210));

z.view = SCCompositeView(z.win, Rect(5,5,140,185));

z.view.background = Color.gray(0.6);

z.view.decorator = FlowLayout(z.view.bounds);

z.knob = EZKnob(z.view, 120@40, "barks", [0.0,1.0, \linear, 0.001, 0.0, ].asSpec, numberWidth: 50); // the example uses EZKnob, available as a Quark..

z.knob.action = {|k| 

z.b.do{|x,i| x[1].set(\freq, (z.a[i].asBark + k.value).barkToHz) };

};

z.knob.knobView.keystep = 0.003;

z.win.onClose = { s.freeAll};

z.win.front;

)

z.a = Array.geom(4, 100, 2); // sines in octaves

// try out with other sine combinations:

//z.a = Array.series(10, 147, 147); // a harmonic series

//z.a = [392, 392 * 5/4, 392 * 3/2]; // a just major chord

//z.a = [392, 392 * 6/5, 392 * 3/2]; // a just minor chord

//z.a = Array.series(20, 0, 1).barkToHz; // a 1 bark scale (there is no interaction between partials at 0 barks)

//z.a = Array.series(20, 0, 0.3).barkToHz; // a 0.3 bark scale (a very rough scale!)


z.b = z.a.collect{|x| {Synth(\sine, [\freq, x, \amp, z.a.size.reciprocal/2])}!2};

// moving the knob you can hear the beatings at low values. Roughness is highest at around

// 0.25 barks, after 0.3-0.4 the individual sounds are heard as separate.


Consonance and dissonance: 


Tenney (1988, [2]) has helped to make clear that the terms 'consonance' and 'dissonance' actually refer to different phenomena depending on their use in different and historical contexts. In this sense, sensory dissonance is what he labels 'Consonance-Dissonance-Concept 5' , a timbral conception which has few correlates in harmonic music theory, although the field of orchestration has affinities with it. It is also important to distinguish between conceptions, explanatory theories, practical uses and aesthetic attitudes towards CDC's. His other CDC's are:


CDC Texture Tuning

1: melodic monody, heterophony  genera, aristoxenian, etc.

2: diphonic organum, bourdon, parallel   pythagorean

3: contrapunctual polyphony just

4: chordal, functional homophony temperaments

5: timbral holophony (?) extended microtonality,

                    degrees of dissonance

Barlow talks about a plane with a tonality-atonality axis and a consonance-dissonance one, and refers to the fact that the harmonic implication of an interval is different from its roughness implications, as roughness hearing implies high and low as in speech perception and not movement and color as in harmonic situations. Despite that, intervals produced by roughness analysis have a high harmonicity [3] value, an agreement which could be thought of as occurring in an open region surrounding the consonance-dissonance axis in this plane. 


Dissonance curves: 


Dissonance curves are made by calculating the roughness between two sets of partials, usually both sets coming from the same sound. All partials are weighted against each other according to the Plomp-Levelt curve for roughness. This makes one point of the curve, the rest of them are arrived at through transposition of one spectrum.  


f = Array.fill(20, {|i| (i+1) * 49}); // freq array, 20 harmonic partials of 49Hz

a = {1}!20; // all partials have equal amplitude

//a = Array.fill(20, {|i| (i + 1).reciprocal}); // amp array 1/n

//a = Array.fill(20, {|i| (i.squared + 1).reciprocal}); // amp array 1/(n**2)


Because of limitations in the resolution of FFT and dissonance analysis, noise gives as result a multitude of varied scales with random characteristics:

//f = Array.rand(10, 49, 1200).sort; // rand frequencies: noise?

//a = {rrand(0.1, 1)}!20; // all random


// generate an f and a (freq, amp) above and then calculate and play their diss curve:

d = Dissonance.make( f, a, 0.99, 3.01 ); // over an interval of 0.99 to 3.01 octaves

d.plot;

d.play;


Most local minima of roughness in the curve correspond to extended just intervals when the spectra are harmonic. Sethares [4] states that Western music uses tunings in close relationship to the timbres of its instruments, in particular the voice and aerophones; also that Gamelan tunings are related to the timbres of its gongs. I think the claim is too broad but that indeed the connection plays a role and can also be used compositionally. 


Compositional uses: 


As a computer-aided-composer, there is a wealth of musical material that can be derived from dissonance curves. Some approaches so far: 


* Composing with a wide range of tunings related to timbres

- use of higher than 5-limit intervals with aid of a 'timbral' grammar

- extending sound-object solfège with a bit of harmony

* Synthesis of dissonance chords, timbres and textures

- dissonance chorales

- 'granular harmony', harmonie concrète


* Real-time analysis-synthesis

- phantoms (spectra), criticism, commentary

Conclusions:


“Timbre can be regarded as a special case of harmony, which is as a special case of rhythm. Texture can be regarded as an expansion of timbre, and conversely, timbre can be viewed as a borderline case of texture, with a gray area between them.

There are also borderline states between texture and intervals and between texture and rhythm. Small or rapid changes in pitch or duration together with psychoacoustic constraints prevent clear identification of the pitches, the intervals or the rhythm. Situations in which intervals turn into texture are intentional in many non-Western musical cultures as well as in contemporary music.” See Cohen & Dubnov (1997) [5].



Bibliography:


[3] Barlow, C. (1980). Bus Journey to Parametron. Cologne: Feedback Papers 21-23. Köln: Feedback Studio Verlag.

Barlow, C. (1987). Two Essays on Theory. Computer Music Journal 11, 44-60.

Benson, D. (1995-2007). Music: A Mathematical Offering. Chapter 4. 

Available at: http://www.maths.abdn.ac.uk/~bensondj/html/maths-music.html

[5] Cohen, D. & Dubnov, S. (1997). Gestalt Phenomena in Musical Texture. In Leman, M. (Ed.),  Music, Gestalt, and 

Computing (386-403). Berlin–Heidelberg: Springer. 

Helmholtz, H.L.F. (1877). On the Sensations of Tone as a Psychological basis for the Theory of Music. New York: Dover.

Plomp R. and Levelt, W. (1965). Tonal Consonance and Critical Bandwidth. Journal of the Acoustical Society 

of America #38, 548-568.

Porres, A.T & Manzolli, J. (2003). Um Modelo Psicoacústico de Rugosidade. PDF obtained from the authors. (In Portuguese).

[4] Sethares, W. (1997). Tuning, Timbre, Spectrum, Scale. Berlin: Springer. 

Schwartz, D. A., Howe, C., Purves, D. (2003). The Statistical Structure of Human Speech Sounds Predicts Musical Universals. 

The Journal of Neuroscience - 23(18):7160-7168. 

Tenney, J. (1984). John Cage and the Theory of Harmony. Soundings 23. Soundings press. 

[2] Tenney, J. (1988). A History of 'Consonance and Dissonance'. New York: Excelsior Music Publishing.

[1] Vassilakis, P.N. (2001) Perceptual and Physical Properties of Amplitude Fluctuation and their Musical Significance. Doctoral 

Dissertation. UCLA. Available at: http://www.acousticslab.org/papers/diss.htm

[6] Xin J., Yingyong Q., (2006). A Many to One Discrete Auditory Transform. 

Available at: http://arxiv.org/abs/math.NA/0603174

(cc 2007) Juan Sebastián Lach Lau . http://homepage.mac.com/jslach/